Papervision3D with AS3Dmod Hello World Example

Sunday, December 21st, 2008 | examples

Bartek Drozdz is a Flash3D rock star. He put together an as3 library called AS3Dmod which allows you to modify the shape of your 3d objects using a modifier stack. This example is a Hello World intro to using the Bend modifier.

source

package
{
	import com.as3dmod.ModifierStack;
	import com.as3dmod.modifiers.Bend;
	import com.as3dmod.plugins.pv3d.LibraryPv3d;
 
	import flash.events.Event;
 
	import org.papervision3d.materials.WireframeMaterial;
	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.view.BasicView;
 
	[SWF(width="640", height="480", backgroundColor="#000000", frameRate="60")]
	public class Papervision3DwithAS3Dmod extends BasicView
	{
		private var plane:Plane;
		private var modifierStack:ModifierStack;
		private var bend:Bend;
 
		public function Papervision3DwithAS3Dmod()
		{
			var wireframeMaterial:WireframeMaterial = new WireframeMaterial(0xcc0000);
			wireframeMaterial.doubleSided = true;
 
			plane = new Plane(wireframeMaterial, 800, 800, 20, 20);
			plane.rotationX = 45;
			plane.rotationY = 45;
 
			modifierStack = new ModifierStack(new LibraryPv3d(), plane);
			bend = new Bend();
			modifierStack.addModifier(bend);
 
			scene.addChild(plane);
 
			startRendering();
		}
 
		override protected function onRenderTick(event:Event=null):void
		{
			plane.rotationY += (viewport.containerSprite.mouseX - plane.rotationY) * .1;
 
			bend.force += (viewport.containerSprite.mouseY / 100 - bend.force) * .3;
			modifierStack.apply();
 
			renderer.renderScene(scene, camera, viewport);
		}
	}
}