Plane3D intersect point

Thursday, November 27th, 2008 | examples

A Plane3D (known commonly as a “Plane” in geometry) is an infinite flat surface. In this example, the Plane3D spans across the x-axis and the z-axis (like a floor) represented by this Number3D:

private const XZPLANE:Number3D = new Number3D(0, 1, 0);

The second number (1), means the Plane3D rotates around the Y-axis. You can think of it like the “1″ is the direction the Plane3D is facing, in this case, “up”. To face toward you, you would set 0, 0, 1. So the Plane3D would point to the monitor (like a wall). To face left to right, you would set 1, 0, 0 (like an alley?).

In this example, the camera is moved up slightly to have more of a bird’s eye view of the Plane3D. You won’t see it at first, but after you click around for awhile, you’ll start to notice where the Plane3D exists.

source

package
{
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import flash.events.MouseEvent;
	import flash.ui.Keyboard;
 
	import org.papervision3d.core.geom.renderables.Vertex3D;
	import org.papervision3d.core.math.Number3D;
	import org.papervision3d.core.math.Plane3D;
	import org.papervision3d.objects.DisplayObject3D;
	import org.papervision3d.objects.primitives.Cylinder;
	import org.papervision3d.scenes.Scene3D;
	import org.papervision3d.view.BasicView;
	import org.papervision3d.view.stats.StatsView;
 
	[SWF(width="640", height="480", backgroundColor="#000000", frameRate="60")]
	public class Plane3DExample extends BasicView
	{
		private const XZPLANE:Number3D = new Number3D(0, 1, 0);
 
		private var plane3D:Plane3D  = new Plane3D(XZPLANE, Number3D.ZERO);
		private var isRotating:Boolean = false;
 
		public function Plane3DExample() 
		{
			camera.y = 200;
 
			startRendering();
 
			stage.addEventListener(MouseEvent.CLICK, clickHandler);
			stage.addEventListener(KeyboardEvent.KEY_DOWN, keyDownHandler);
		}
 
		private function keyDownHandler(event:KeyboardEvent):void
		{
			//toggle rotating
			if(event.keyCode == Keyboard.CONTROL)
			{
				isRotating = (isRotating == false) ? true : false;
			}
 
			//rebuild scene
			if(event.keyCode == Keyboard.SHIFT)
			{
				scene = new Scene3D();
			}
		}
 
 
		private function clickHandler(event:MouseEvent):void
		{
			var ray:Number3D = camera.unproject(viewport.containerSprite.mouseX, viewport.containerSprite.mouseY);
			ray = Number3D.add(ray, camera.position);
 
			var cameraVertex3D:Vertex3D = new Vertex3D(camera.x, camera.y, camera.z);
			var rayVertex3D:Vertex3D = new Vertex3D(ray.x, ray.y, ray.z);
 
			var intersectPoint:Vertex3D = plane3D.getIntersectionLine(cameraVertex3D, rayVertex3D);
 
			var cylinder:Cylinder = new Cylinder(null, 10, 100, 1, 1);
			cylinder.x = intersectPoint.x;
			cylinder.y = intersectPoint.y;
			cylinder.z = intersectPoint.z;
 
			//the closer to the center, the larger the tower
			cylinder.scale = 1000 / cylinder.distanceTo(new DisplayObject3D());
			//readjust y based on scale (half height times scale)
			cylinder.y += 50 * cylinder.scale;
 
 
			scene.addChild(cylinder);
		}
 
		override protected function onRenderTick(event:Event=null):void
		{
			if(isRotating)
			{
				camera.moveForward(1000);
				camera.yaw(.5);
				camera.moveBackward(1000);
			}
 
			renderer.renderScene(scene, camera, viewport);
		}
	}
 
}

Tags: Plane3D, ray, Vertex3D

Erdem

I want to develope an AR application: When I click anywhere of the screen it gets the coordinates of the intersection point of the marker and the click, and locates the model to that coordinates. If there isn't any way to do this with PV3D please write down here and give me another library name or an other way that you try of see before.In this example it was developed with the intersction of a fixed plane and click. I want to do do this in AR medium. My plane is not fixed. The normals change with the movement of the marker... Thank you......

Arindam Mojumder

how can I create this kind of slider?
http://www.citroen.co.uk/home/...

John Lindquist

It's a simple/stupid way of orbiting the camera.

The camera starts a -1000 z.

So, you move it 1000 forward (to zero), rotate a little bit, then move a 1000 backward (back out to -1000 z) to achieve a sort of fake orbiting.

Hope that makes sense.

LQH

if(isRotating)
{
camera.moveForward(1000);
camera.yaw(.5);
camera.moveBackward(1000);
}

I wonder why there is a need to add "camera.moveForward(1000);" and "camera.moveBackward(1000);" in this function. I comment these two statements then it doesn't rotate anymore! Please tell me why. :<